testDecompress

fn testDecompress(container: Container, compressed: []const u8, expected_plain: []const u8) !void {
    var aw: std.Io.Writer.Allocating = .init(testing.allocator);
    defer aw.deinit();

    // Decompress once using the normal methods.
    {
        var in: std.Io.Reader = .fixed(compressed);
        var decompress: Decompress = .init(&in, container, &.{});
        const decompressed_len = try decompress.reader.streamRemaining(&aw.writer);
        try testing.expectEqual(expected_plain.len, decompressed_len);
        try testing.expectEqualSlices(u8, expected_plain, aw.written());
    }

    // Decompress again by streaming one byte at a time to check that there aren't
    // any problems with things like writing partial matches, etc.
    aw.clearRetainingCapacity();
    {
        var in: std.Io.Reader = .fixed(compressed);
        var decompress: Decompress = .init(&in, container, &.{});
        var decompressed_len: usize = 0;
        while (true) {
            decompressed_len += decompress.reader.stream(&aw.writer, .limited(1)) catch |err| switch (err) {
                error.EndOfStream => break,
                else => |e| return e,
            };
        }
        try testing.expectEqual(expected_plain.len, decompressed_len);
        try testing.expectEqualSlices(u8, expected_plain, aw.written());
    }
}